This Notebook contains supplementary material related to the paper
Stanley Rabinowitz, “Relationships Between Six Excircles”, Sangaku Journal of Mathematics, 3 (2019)73-90
which can be found at http://www.sangaku-journal.eu/2019/SJM_2019_73-90_Rabinowitz.pdf.

This Notebook is Copyright © September 2019 by Stanley Rabinowitz (stan.rabinowitz@comcast.net) and is published with open access. This Notebook is distributed under the terms of the Creative Commons Attribution License which permits any use, distribution, and reproduction in any medium, provided the original author and the source are credited.
------------------------------------------------------------------------------

Proof of Theorem 8.3

(* ================ Set up equations ================= *)

c=Pi/2-a-b;
(* WLOG we assume R=1/2 *)
AB=Sin[2c];
BC=Sin[2a];
CA=Sin[2b];
(* Use the Law of Sines *)
BD=Sin[a]AB/Sin[a+2c];
CE=Sin[b]BC/Sin[b+2a];
AF=Sin[c]CA/Sin[c+2b];
CD=Sin[a]CA/Sin[a+2b];
AE=Sin[b]AB/Sin[b+2c];
BF=Sin[c]BC/Sin[c+2a];
PA=Sin[c]CA/Sin[c+a];
PB=Sin[a]AB/Sin[a+b];
PC=Sin[b]BC/Sin[b+c];
PD=Sin[a]Sin[b]AB/(Sin[a+b]Sin[a+2c]);
PE=Sin[b]Sin[c]BC/(Sin[b+c]Sin[b+2a]);
PF=Sin[c]Sin[a]CA/(Sin[c+a]Sin[c+2b]);
K1=(1/2)PB*BD*Sin[b];
K2=(1/2)PC*CD*Sin[c];
K3=(1/2)PC*CE*Sin[c];
K4=(1/2)PA*AE*Sin[a];
K5=(1/2)PA*AF*Sin[a];
K6=(1/2)PB*BF*Sin[b];
s1=(PB+BD+PD)/2;
s2=(PD+CD+PC)/2;
s3=(PC+CE+PE)/2;
s4=(PE+AE+PA)/2;
s5=(PA+AF+PF)/2;
s6=(PF+BF+PB)/2;
r1=K1/(s1-BD);
r2=K2/(s2-CD);
r3=K3/(s3-CE);
r4=K4/(s4-AE);
r5=K5/(s5-AF);
r6=K6/(s6-BF);
rad=Pi/180;

Discovery of the Theorem

(* Pick a random angle measure like 17º.
Let b=60ºand a=17º, and look for an integer relationship between the ri *)

bval=Pi/3;
aval=17 rad;
{nr1,nr2,nr3,nr4,nr5,nr6}={r1,r2,r3,r4,r5,r6}/.{a->aval,b->bval};
Quiet[FindIntegerNullVector[N[{nr1,nr2,nr3,nr4,nr5,nr6},50],20]]

(* Look for a linear relationship between the 1/ri *)

bval=Pi/3;
aval=17 rad;
{nr1,nr2,nr3,nr4,nr5,nr6}={r1,r2,r3,r4,r5,r6}/.{a->aval,b->bval};
Quiet[FindIntegerNullVector[N[{1/nr1,1/nr2,1/nr3,1/nr4,1/nr5,1/nr6},50],20]]

(* The relationship seems to be 1/r1+1/r3+1/r4+1/r6=1/r2+1/r5 *)

(* ====================================================================== *)

Proof of the Theorem

bval=Pi/3;
{nr1,nr2,nr3,nr4,nr5,nr6}={r1,r2,r3,r4,r5,r6}/.b->bval;
expr=1/nr1-1/nr2+1/nr3+1/nr4-1/nr5+1/nr6;
Simplify[expr]