This Notebook contains supplementary material related to the paper
Stanley Rabinowitz, “Relationships Between Six Incircles”, Sangaku Journal of Mathematics, 3(2019)51–66
which can be found at http://www.sangaku-journal.eu/2019/SJM_2019_51-66_Rabinowitz.pdf.

This Notebook is Copyright © August 2019 by Stanley Rabinowitz (stan.rabinowitz@comcast.net) and is published with open access. This Notebook is distributed under the terms of the Creative Commons Attribution License which permits any use, distribution, and reproduction in any medium, provided the original author and the source are credited.
------------------------------------------------------------------------------

Proof of Theorem 6.2

(* ================ Set up equations ================= *)

BD=Sin[a]Sin[2c]/Sin[a+2c];
CE=Sin[b]Sin[2a]/Sin[b+2a];
AF=Sin[c]Sin[2b]/Sin[c+2b];
CD=Sin[a]Sin[2b]/Sin[a+2b];
AE=Sin[b]Sin[2c]/Sin[b+2c];
BF=Sin[c]Sin[2a]/Sin[c+2a];
PA=Sin[c]Sin[2b]/Sin[c+a];
PB=Sin[a]Sin[2c]/Sin[a+b];
PC=Sin[b]Sin[2a]/Sin[b+c];
PD=Sin[a]Sin[b]Sin[2c]/(Sin[a+b]Sin[a+2c]);
PE=Sin[b]Sin[c]Sin[2a]/(Sin[b+c]Sin[b+2a]);
PF=Sin[c]Sin[a]Sin[2b]/(Sin[c+a]Sin[c+2b]);
K1=(1/2)PB*BD*Sin[b];
K2=(1/2)PC*CD*Sin[c];
K3=(1/2)PC*CE*Sin[c];
K4=(1/2)PA*AE*Sin[a];
K5=(1/2)PA*AF*Sin[a];
K6=(1/2)PB*BF*Sin[b];
s1=(PB+BD+PD)/2;
s2=(PD+CD+PC)/2;
s3=(PC+CE+PE)/2;
s4=(PE+AE+PA)/2;
s5=(PA+AF+PF)/2;
s6=(PF+BF+PB)/2;
r1=K1/s1;
r2=K2/s2;
r3=K3/s3;
r4=K4/s4;
r5=K5/s5;
r6=K6/s6;
rad=Pi/180;

(* Discovery of the Theorem. Pick a random angle measure like 17º
for angle C. Let a=b=60º, c=d=17º, and look for
 an integer relationship between the ri *)

(* There is no linear relationship between the ri *)
bval=Pi/3;
cval=17 rad;
aval=Pi/2-bval-cval;
{nr1,nr2,nr3,nr4,nr5,nr6}={r1,r2,r3,r4,r5,r6}/.{a->aval,b->bval,c->cval};
Quiet[FindIntegerNullVector[N[{nr1,nr2,nr3,nr4,nr5,nr6},50],20]]

(* There is no linear relationship between the 1/ri *)
bval=Pi/3;
cval=17 rad;
aval=Pi/2-bval-cval;
{nr1,nr2,nr3,nr4,nr5,nr6}={r1,r2,r3,r4,r5,r6}/.{a->aval,b->bval,c->cval};
Quiet[FindIntegerNullVector[N[{1/nr1,1/nr2,1/nr3,1/nr4,1/nr5,1/nr6},50],20]]

(* Look for a linear relationship between the pairs ri*rj *)

x2list=Apply[Times,Subsets[{x1,x2,x3,x4,x5,x6},{2}],2]

bval=Pi/3;
cval=17 rad;
aval=Pi/2-bval-cval;
{nr1,nr2,nr3,nr4,nr5,nr6}={r1,r2,r3,r4,r5,r6}/.{a->aval,b->bval,c->cval};rel2=Quiet[FindIntegerNullVector[N[Apply[Times,Subsets[{nr1,nr2,nr3,nr4,nr5,nr6},{2}],2],50],20]]

(* Look for a linear relationship between the triples ri*rj*rk *)

x3list=Apply[Times,Subsets[{x1,x2,x3,x4,x5,x6},{3}],2]

bval=Pi/3;
cval=17 rad;
aval=Pi/2-bval-cval;
{nr1,nr2,nr3,nr4,nr5,nr6}={r1,r2,r3,r4,r5,r6}/.{a->aval,b->bval,c->cval};rel3=Quiet[FindIntegerNullVector[N[Apply[Times,Subsets[{nr1,nr2,nr3,nr4,nr5,nr6},{3}],2],50],20]]

rel3*x3list

(* The relationship seems to be
r1 r2 r3 - r1 r3 r4 - r2 r3 r4 + r3 r4 r5 + r3 r4 r6 - r4 r5 r6 = 0 *)

(* ====================================================================== *)

(* Proof of the relationship: *)

bval=Pi/3;
aval=Pi/2-bval-c;
{nr1,nr2,nr3,nr4,nr5,nr6}={r1,r2,r3,r4,r5,r6}/.{a->aval,b->bval};
expr=nr1 nr2 nr3 - nr1 nr3 nr4 - nr2 nr3 nr4 + nr3 nr4 nr5 + nr3 nr4 nr6 - nr4 nr5 nr6;
Simplify[expr]