This Notebook contains supplementary material related to the paper
Stanley Rabinowitz, “Relationships Between Six Incircles”, Sangaku Journal of Mathematics, 3(2019)51–66
which can be found at http://www.sangaku-journal.eu/2019/SJM_2019_51-66_Rabinowitz.pdf.

This Notebook is Copyright © August 2019 by Stanley Rabinowitz (stan.rabinowitz@comcast.net) and is published with open access. This Notebook is distributed under the terms of the Creative Commons Attribution License which permits any use, distribution, and reproduction in any medium, provided the original author and the source are credited.
------------------------------------------------------------------------------

Discovery ad Proof of Theorem 6.3

(* =============== Set up the equations ================== *)

a=Pi/4;
b=Pi/12;
c=Pi/6;
BD=Sin[a]Sin[2c]/Sin[a+2c];
CE=Sin[b]Sin[2a]/Sin[b+2a];
AF=Sin[c]Sin[2b]/Sin[c+2b];
CD=Sin[a]Sin[2b]/Sin[a+2b];
AE=Sin[b]Sin[2c]/Sin[b+2c];
BF=Sin[c]Sin[2a]/Sin[c+2a];
PA=Sin[c]Sin[2b]/Sin[c+a];
PB=Sin[a]Sin[2c]/Sin[a+b];
PC=Sin[b]Sin[2a]/Sin[b+c];
PD=Sin[a]Sin[b]Sin[2c]/(Sin[a+b]Sin[a+2c]);
PE=Sin[b]Sin[c]Sin[2a]/(Sin[b+c]Sin[b+2a]);
PF=Sin[c]Sin[a]Sin[2b]/(Sin[c+a]Sin[c+2b]);
K1=(1/2)PB*BD*Sin[b]//Simplify;
K2=(1/2)PC*CD*Sin[c]//Simplify;
K3=(1/2)PC*CE*Sin[c]//Simplify;
K4=(1/2)PA*AE*Sin[a]//Simplify;
K5=(1/2)PA*AF*Sin[a]//Simplify;
K6=(1/2)PB*BF*Sin[b]//Simplify;
s1=(PB+BD+PD)/2//Simplify;
s2=(PD+CD+PC)/2//Simplify;
s3=(PC+CE+PE)/2//Simplify;
s4=(PE+AE+PA)/2//Simplify;
s5=(PA+AF+PF)/2//Simplify;
s6=(PF+BF+PB)/2//Simplify;
radius1=K1/s1//FullSimplify;
radius2=K2/s2//FullSimplify;
radius3=K3/s3//FullSimplify;
radius4=K4/s4//FullSimplify;
radius5=K5/s5//FullSimplify;
radius6=K6/s6//FullSimplify;

(* Define the values for the ri listed in the paper *)
r1=(Sqrt[2]-1)(Sqrt[3]-1)/4;
r2=(-10-7Sqrt[2]+6Sqrt[3]+4Sqrt[6])/4;
r3=(9-7Sqrt[2]-5Sqrt[3]+4Sqrt[6])/4;
r4=(2-Sqrt[3])/(2(-1+Sqrt[2]+Sqrt[3]));
r5=(-3Sqrt[2]+2Sqrt[3]+Sqrt[6])/24;
r6=(1+Sqrt[3]-Sqrt[6])/4;

(* Show that these values agree with the values found previously *)

Simplify[r1-radius1]

Simplify[r2-radius2]

Simplify[r3-radius3]

FullSimplify[r4-radius4]

Simplify[r5-radius5]

Simplify[r6-radius6]

(* Prove the 6 equalities given in the paper in Theorem 6.3 *)

Simplify[2/r1^4+8/r3^4+6/r4^4+5/r5^4-14/r2^4-20/r6^4]

Simplify[3/r1^2+3/r2^2+3/r4^2-3/r3^2-2/r5^2-3/r6^2]

Simplify[2/r1+2/r2+1/r5+1/r6-3/r3-2/r4]

Simplify[3r1+5r3+55r4+22r6-4r2-75r5]

Simplify[2r1 r3+3r2 r4+9r5 r1+9r6 r2-27r3 r5-r4 r6]

(* Prove the relation give by Theorem 6.1 *)
(* Note that in Theorem 6.1, angle B is 60º, but in Theorem 6.3, it is angle C that is 60º. *)

Simplify[1/r1+1/r3+1/r6-1/r2-1/r4-1/r5]

(* =========== How these and some other relationships were discovered ============ *)

FindIntegerNullVector[N[{1/r1^4,1/r2^4,1/r3^4,1/r4^4,1/r5^4,1/r6^4},50],100]

FindIntegerNullVector[N[{1/r1^3,1/r2^3,1/r3^3,1/r4^3,1/r5^3,1/r6^3},50],100]

FindIntegerNullVector[N[{1/r1^2,1/r2^2,1/r3^2,1/r4^2,1/r5^2,1/r6^2},50],100]

FindIntegerNullVector[N[{1/r1,1/r2,1/r3,1/r4,1/r5,1/r6},50],100]

FindIntegerNullVector[N[{r1,r2,r3,r4,r5,r6},50],100]

u1=FindIntegerNullVector[N[{r1,r2,r3,r4,r5},50],100]

u2=FindIntegerNullVector[N[{r1,r2,r3,r4,r6},50],100]

u3=FindIntegerNullVector[N[{r2,r3,r4,r5,r6},50],100]

(* combining u1, u2, and u3 gives 3r1+5r3+55r4+22r6-4r2-75r5 *)
{19,4,-5,-33,9,0}+{-22,-4,5,30,0,-3}+{0,4,-5,-52,66,-19}

FindIntegerNullVector[N[{r1^2,r2^2,r3^2,r4^2,r5^2,r6^2},50],200]

xlist=Apply[Times,Subsets[{x1,x2,x3,x4,x5,x6},{2}],2]

rel2=FindIntegerNullVector[N[Apply[Times,Subsets[{r1,r2,r3,r4,r5,r6},{2}],2],50],100]

ans2=rel2*xlist

Select[ans2,#=!=0&]

FindIntegerNullVector[N[{r1 r3,r3 r5,r5 r1,r2 r4,r4 r6,r6 r2},50],100]

(* Proofs for the ones not given in the paper *)

Simplify[12/r1^3+12/r2^3-14/r3^3-28/r4^3+5/r5^3+38/r6^3]

Simplify[r1+r4-3r5+r6]

Simplify[58r1^2-2r2^2-2r3^2+112r4^2-150r5^2-5r6^2]

Simplify[r1 r4-r2 r5 -r2 r6 -2 r3 r4 +r3 r6+2r4 r5]