This Notebook contains supplementary material related to the paper
Stanley Rabinowitz, “Relationships Between Six Incircles”, Sangaku Journal of Mathematics, 3(2019)51–66
which can be found at http://www.sangaku-journal.eu/2019/SJM_2019_51-66_Rabinowitz.pdf.

This Notebook is Copyright © August 2019 by Stanley Rabinowitz (stan.rabinowitz@comcast.net) and is published with open access. This Notebook is distributed under the terms of the Creative Commons Attribution License which permits any use, distribution, and reproduction in any medium, provided the original author and the source are credited.
------------------------------------------------------------------------------

Proof of Theorem 7.1

(* ================ Set up equations ================= *)

AB=Sin[c+d];
AC=Sin[a+b];
BC=Sin[a+b+c+d];
AF=Sin[a+b]Sin[d]/Sin[a+b+c];
BF=BC Sin[c]/Sin[a+b+c];
AE=Sin[c+d]Sin[a]/Sin[b+c+d];
CE=BC Sin[b]/Sin[b+c+d];
PB=BC Sin[c]/Sin[b+c];
PC=BC Sin[b]/Sin[b+c];
PE=CE Sin[d]/Sin[b+c];
PF=BF Sin[a]/Sin[b+c];
BD=BF AE BC/(BF AE+AF CE);
CD=AF CE BC/(BF AE+AF CE);
PA=Sqrt[AB^2+PB^2-2AB PB Cos[a]];
PD=PA BD CE / (BC AE);
K1=(1/2)PB*BD*Sin[b];
K2=(1/2)PC*CD*Sin[c];
K3=(1/2)PC*CE*Sin[d];
K4=(1/2)AE*PE*Sin[b+c+d];
K5=(1/2)AF*PF*Sin[a+b+c];
K6=(1/2)PB*BF*Sin[a];
s1=(PB+BD+PD)/2;
s2=(PD+CD+PC)/2;
s3=(PC+CE+PE)/2;
s4=(PE+AE+PA)/2;
s5=(PA+AF+PF)/2;
s6=(PF+BF+PB)/2;
r1=K1/s1;
r2=K2/s2;
r3=K3/s3;
r4=K4/s4;
r5=K5/s5;
r6=K6/s6;
rad=Pi/180;

(* Proof of the relationship: *)

{nr1,nr2,nr3,nr4,nr5,nr6}={r1,r2,r3,r4,r5,r6}/.{a->10rad,b->30rad,c->80rad,d->20rad};
expr=5nr1+6nr2-nr3+nr4-3nr5-15nr6;
expr2=TrigToExp[expr];
FullSimplify[expr2]

(* ====================================================================== *)

(* How this relationship was discovered. *)

(* Vary each of a, b, c, and d from 10 to 90 in steps of 10
and look for a resulting linear relationship involving all 6 terms. *)
step=10;
For[ia=step,ia<=90,ia+=step,
For[ib=step,ib<=90,ib+=step,
For[ic=ib,ic<=90,ic+=step,
If[ia+ib+ic≥180,Break[]];
For[id=step,id<=90,id+=step,
If[ia+ib+ic+id≥180,Break[]];
If[ia==id&&ib==ic,Continue[]];
{nr1,nr2,nr3,nr4,nr5,nr6}={r1,r2,r3,r4,r5,r6}/.{a->ia rad,b->ib rad,c->ic rad,d->id rad};
ans=Quiet[FindIntegerNullVector[N[{nr1,nr2,nr3,nr4,nr5,nr6},100],50]];
If[Head[ans]=!=FindIntegerNullVector,
If[Count[ans,0]≠0,Continue[]];
If[ans[[1]]<0,ans=-ans];
Print["a=",ia," b=",ib," c=",ic," d=",id,"   ",ans];
]
]
]
]
]