This Notebook contains supplementary material related to the paper
Stanley Rabinowitz, “Relationships Between Six Incircles”, Sangaku Journal of Mathematics, 3(2019)51–66
which can be found at http://www.sangaku-journal.eu/2019/SJM_2019_51-66_Rabinowitz.pdf.

This Notebook is Copyright © August 2019 by Stanley Rabinowitz (stan.rabinowitz@comcast.net) and is published with open access. This Notebook is distributed under the terms of the Creative Commons Attribution License which permits any use, distribution, and reproduction in any medium, provided the original author and the source are credited.
------------------------------------------------------------------------------

Proof of Theorem 7.2

(* ================ Set up equations ================= *)

AB=Sin[c+d];
AC=Sin[a+b];
BC=Sin[a+b+c+d];
AF=Sin[a+b]Sin[d]/Sin[a+b+c];
BF=BC Sin[c]/Sin[a+b+c];
AE=Sin[c+d]Sin[a]/Sin[b+c+d];
CE=BC Sin[b]/Sin[b+c+d];
PB=BC Sin[c]/Sin[b+c];
PC=BC Sin[b]/Sin[b+c];
PE=CE Sin[d]/Sin[b+c];
PF=BF Sin[a]/Sin[b+c];
BD=BF AE BC/(BF AE+AF CE);
CD=AF CE BC/(BF AE+AF CE);
PA=Sqrt[AB^2+PB^2-2AB PB Cos[a]];
PD=PA BD CE / (BC AE);
K1=(1/2)PB*BD*Sin[b];
K2=(1/2)PC*CD*Sin[c];
K3=(1/2)PC*CE*Sin[d];
K4=(1/2)AE*PE*Sin[b+c+d];
K5=(1/2)AF*PF*Sin[a+b+c];
K6=(1/2)PB*BF*Sin[a];
s1=(PB+BD+PD)/2;
s2=(PD+CD+PC)/2;
s3=(PC+CE+PE)/2;
s4=(PE+AE+PA)/2;
s5=(PA+AF+PF)/2;
s6=(PF+BF+PB)/2;
r1=K1/s1;
r2=K2/s2;
r3=K3/s3;
r4=K4/s4;
r5=K5/s5;
r6=K6/s6;
rad=Pi/180;

(* Proof of the relationship: *)

{nr1,nr2,nr3,nr4,nr5,nr6}={r1,r2,r3,r4,r5,r6}/.{a->4t,b->5t,c->3t,d->2t};
expr=1/nr1-1/nr2+1/nr3+1/nr4-1/nr5-1/nr6;
Simplify[expr]

(* ====================================================================== *)

(* How this relationship was discovered. *)

(* Vary each of ak, bk, ck, and dk from 1 to 9
and look for a resulting inverse linear relationship
involving multiples of t. We pick a random value of t,
 in particular, t=1º. *)
t=1rad;
For[ak=1,ak<10,ak++,
For[bk=1,bk<10,bk++,
If[bk==ak,Continue[]];
For[ck=1,ck<bk,ck++,
If[ck==bk||ck==ak,Continue[]];
For[dk=1,dk<10,dk++,
If[dk==ck||dk==bk||dk==ak,Continue[]];
{nr1,nr2,nr3,nr4,nr5,nr6}={r1,r2,r3,r4,r5,r6}/.{a->ak t,b->bk t,c->ck t,d->dk t};
ans=Quiet[FindIntegerNullVector[N[{1/nr1,1/nr2,1/nr3,1/nr4,1/nr5,1/nr6},100],50]];
If[Head[ans]=!=FindIntegerNullVector,
Print["ak=",ak," bk=",bk," ck=",ck," dk=",dk,"   ",ans];
]
]
]
]
]

(* The conjectured relationship seems to be when a=4t, b=5t, c=3t, and d=2t, then 1/r1-1/r2+1/r3+1/4-1/r5-1/r6=0 *)